options ls=75 nodate;

data one;
   drop i;
   input a b @;
   b=10*b;
   bs=b*b;
   do i=1 to 3;
      input y @;
      output;
   end;
   cards;
1 1 7.9 9.2 10.5
2 1 8.1 8.6 10.1
3 1 15.3 16.1 17.5
1 2 11.2 12.8 13.3
2 2 11.5 12.7 13.7
3 2 16.6 18.5 19.2
1 3 12.1 12.6 14.0
2 3 13.7 14.4 15.4
3 3 18.0 20.8 21.0
1 4 9.1 10.8 12.5
2 4 11.3 12.5 14.5
3 4 17.2 18.4 18.9
;
run;

proc glm;
   class a b;
   model y=a|b;
   contrast 'linear effect' b -3 -1 1 3;
   contrast 'quadratic effect' b 1 -1 -1 1;
   contrast 'cubic effect' b -1 3 -3 1;
   means a|b;
   output out=two p=p;
run;
symbol1 i=join value=dot; symbol2 i=join value=plus;
symbol3 i=join value=diamond; symbol2 i=join value=star;

/* in class on Oct. 14, a question was asked about how to specify
the scale of the vertical axis in a plot using Cartesian coordinates.
You can change the default (chosen according to data) using an AXIS
statement with an ORDER option, then specifying that axis in the
PLOT statement within GPLOT, as in the following code */

axis1 order=(5 to 30 by 1);

proc gplot;
   plot p*b=a/vaxis=axis1;
run;