options ls=75 nodate;

DATA spiders;
   DO sex= "m","f";
      INPUT y @;
      *y=log(y);  
      ismale=(sex="m"); /* a boolean expression, taking value 0 or 1 */
      OUTPUT;
   END;
   LABEL y="length";
   *LABEL y="log-length";
   CARDS;
5.2  8.25
4.7  9.8
5.7  6.1
5.65  9
5.75  9.5
4.7  9.95
4.8  10.8
6.2  9.3
5.5  6.3
5.95  8.3
5.75  5.9
5.95  6.6
5.4  8.75
5.65  8.35
5.9  7.05
7.5  7.05
5.2  7.55
6.2  7
5.85  8.7
7  8.3
6.45  8.45
6.35  8.1
5.85  7.8
5.75  8
6.1  7.95
6.55  7.55
6.95  9.1
6.8  8
6.35  7.5
5.8  9.6
;
RUN;

PROC GPLOT;
   PLOT y*sex;
RUN;
QUIT;

PROC GLM;
   MODEL y=ismale;  /* ismale is a numeric variable, valued 0 or 1 */
RUN;
PROC GLM;
   CLASS sex;  /* sex is a class variable w/ two levels, 'm' or 'f' */
   MODEL y=sex;
   OUTPUT OUT=residz p=p r=r;
RUN;
AXIS1 OFFSET=(10,5);  
/* offset scooches tick marks in towards middle of horizontal axis */
PROC GPLOT;  
PLOT r*sex / HAXIS=axis1;
RUN;
QUIT;
PROC UNIVARIATE DATA=residz NOPRINT;
   HISTOGRAM R;
   VAR r;
RUN;
PROC ANOVA;
   CLASS sex;
   MODEL y=sex;
   MEANS sex/hovtest;
RUN;
PROC TTEST;
   CLASS sex;
   VAR y;
RUN;