options ls=75 formdlim="-";

data one;
   input treatment $3. opredux;
   if treatment="c" then do;  lime="no ";  floc="no "; end;
   if treatment="f" then do;  lime="no ";  floc="yes"; end;
   if treatment="l" then do;  lime="yes ";  floc="no"; end;
   if treatment="lf" then do;  lime="yes ";  floc="yes"; end;
   cards;
c            53  
c            67  
c            57  
f            58  
f            68  
f            57  
l            50  
l            44  
l            56  
lf           89  
lf           80  
lf           77  
;
run;

proc glm;
   class  treatment;
   model  opredux=treatment;
   estimate "interaction" treatment 1 -1 -1 1;
   contrast "interaction" treatment 1 -1 -1 1;
   estimate "floc when lime abs" treatment -1 1; 
   estimate "floc when lime pres" treatment 0 0 -1 1;
run;
proc glm;
   class lime floc ;
   model opredux=lime|floc;
   lsmeans lime*floc/slice=lime;
   output out=two p=yhat r=r;
run;
proc gplot;
   plot r*yhat;
run;

/* if PROC GLIMMIX is available try this*/
/*
proc glimmix;
   class lime floc ;
   model opredux=lime|floc;
   lsmeans lime*floc/slicediff=lime;
run;
*/