options ls=75 nodate;
/*-----------------------------------------------------------------
|  Data from Mike Rodriguez - Soils from 2 sources p= buldozed pit |
| b = berm around pit (richer soil).  Half of soils innoculated    |
| with soil from nearby pine/hardwood forest, half uninnoculated.  |
| Loblolly pine seeds were planted (19 per treatment) and heights  |
| of seedlings recorded.                                           |
 ----------------------------------------------------------------*/

data soils;
  input soil $ inoc $ @;  trt+1;           *--- Counter 1,2,...    ;
     do rep = 1 to 19; input height @;
     lheight = log(height);                 *--- Logs ??   ;
   output;   end;
  cards;
b i 29.5 30.0 28.5 28.5 24.0 24.0 23.5 28.5 30.5 25.0 24.6 32.0
    31.5 26.5 26.5 26.5 26.5 23.0 22.0
b u 20.5 20.5 20.0 25.5 27.5 24.0 16.0 17.0 26.5 27.0 14.5 18.5
    18.5 20.0 16.5 19.0 18.5 15.0 22.5
p i 20.5 14.0 14.0 12.0 13.0 15.0 13.0 13.0 18.0 15.0 16.0 11.0
    14.0 15.0 13.5 13.0 13.5 15.0 20.5
p u 11.5 10.0 9.5  11.5 14.0 10.0 10.0 12.5 11.0 10.0  9.0  8.5
    11.0  7.0  9.5 12.0 12.5 12.0 14.0
 ;

proc print data=soils;
   title "trt variable indexes the four combos of SOIL and INOC";
   var trt soil inoc height;
run;

proc glm; 
    class trt;  
    *model height = trt;
    model lheight = trt;
    /* break up SS(trt) into 3 orthogonal components */
    contrast "berm - pit" trt 1 1 -1 -1;
    contrast "inoculated - uninoculated" trt 1 -1 1 -1;
    contrast "interaction" trt 1 -1 -1 1;
    means trt/hovtest;  /* a test for equality of variances (hov=homogeneity of variance)*/
    means trt/tukey;    /* Tukey's procedure to control exptwise error for ALL PAIRWISE comps */
   output out=two r=r p=p;
run;


proc gplot data=two; 
plot r*p = trt;
run;

symbol1 interpolate=join value=dot color=blue;
symbol2 interpolate=join value=star color=red;
proc gplot data=two;
plot p*soil= inoc;
plot p*inoc= soil;
run;
proc glm;
   class soil inoc;
   model lheight=soil|inoc;
    contrast 'Soils' soil -1 1;
    contrast 'Innoculum within soil 1' inoc -1 1
    soil*inoc -1 1 0 0;
    contrast 'Innoculum in 2' inoc -1 1
    soil*inoc 0 0 -1 1;
run;

/*
ods graphics on;
proc glimmix;
   class soil inoc;
   model lheight=soil|inoc;
   lsmeans soil*inoc/plot=meanplot(sliceby=soil join);
run;
*/