DATA PLANTS; 
   TITLE "ENZYME ACTIVITY";
   DO T=1 TO 30; Hour=4*T;
      INPUT Y @@;
      PI=3.1415926; 
      S1=SIN(2*PI*T/3);
      C1=COS(2*PI*T/3); 
      OUTPUT;
   END; 
   CARDS; 
265.945 290.385 251.099 285.870 379.370 301.173 283.096 306.199 341.696
246.352 310.648 276.348 234.870 314.744 261.363 321.780 313.289 253.460
307.988 303.909 284.128 252.886 317.432 287.160 213.168 308.458 296.351
283.666 333.544 316.998
;
RUN; 
PROC REG DATA=PLANTS;  
   MODEL Y = S1 C1/SS1;
   OUTPUT OUT=OUT1 PREDICTED=P RESIDUAL=R;
RUN; 
DATA ANNO;
   SET OUT1;
   XSYS="2";
   YSYS="2"; 
   FUNCTION="MOVE";
   X=4*T;
   OUTPUT;
   Y=P;
   FUNCTION = "DRAW";
   OUTPUT; 
RUN;
PROC GPLOT DATA=OUT1 ANNOTATE=ANNO;
   PLOT (Y P)*Hour/OVERLAY HMINOR=0 VMINOR=0; 
   SYMBOL1 V=DIAMOND I=NONE C=BLACK W=3;  
   SYMBOL2 V=DOT I=SPLINE C=BLACK L=1 ; 
   TITLE "ENZYME ACTIVITY";
RUN; 
PROC SPECTRA DATA=PLANTS OUT=OUT2 WHITETEST COEF;
   VAR Y; 
RUN;
DATA OUT2;
   SET OUT2;
   SSE = P_01;
   TITLE "ENZYME DATA"; 
   IF PERIOD=3 OR PERIOD=. THEN SSE=0; 
   IF ROUND (FREQ, .0001) = 3.1416 THEN SSE = .5*P_01; 
RUN;
PROC PRINT DATA=OUT2;
   SUM SSE; 
RUN;
PROC GPLOT DATA=OUT2;
   PLOT P_01*FREQ /HMINOR=0 VMINOR=0;
   WHERE FREQ>0; 
   SYMBOL1 V=DOT I=NEEDLE C=BLACK;
   TITLE "ENZYME PERIODOGRAM"; 
   LABEL P_01 = "Ordinate"; 
RUN; 
QUIT;