/*---------------------------------------
|  Generate several ARIMA models - graph |
|  data above ACF etc.  using templates  |
|  color by significance                 |
 ---------------------------------------*/


proc greplay  nofs; igout=work.gseg;
     delete _all_;
  ** clear out the existing graphics catalog ***;
goptions reset=all;
goptions htitle=1.5 htext=1 ftext=centb
targetdevice=pscolor;
data a;
Y1L=0; Y2L=0; Y3L=0; E1=0;
  do t=1 to 365; E=normal(9800377);
  Y1 = .8*Y1L + .6*E;
  Y2 = .8*e + .6*E1;
  Y3 = .8*Y3L + .65*E + .5*E1;
  output; Y1L=Y1; Y3L=Y3; E1=E;
  end;
  data a; set a; AR1=Y1+10; MA1=Y2+10; ARMA11=.6*Y3+10;
  drop E E1 Y1 Y2 Y3 Y1L Y2L Y3L;
  proc print data=a (obs=10);
  proc gplot; plot (AR1 MA1 ARMA11)*t/overlay legend;
  symbol1 v=none i=join w=2;
  title "Time Series";
  proc arima;
    i var = AR1 nlag=20 outcov=outar;
    i var = MA1 nlag=20 outcov=outma;
    i var = ARMA11 nlag=20 outcov=outarma;
  run;
  proc print data=outar;
  data outar; set outar;
  u95 = 1.96*stderr; l95=-1*u95;
  u=1/sqrt(300); l=-1*u;
  corr1=corr;  if abs(corr)<u95 then corr=.;  else corr1=.;
  pcorr1=partcorr;  if abs(partcorr)<u then partcorr=.;  else pcorr1=.;
  invcorr1=invcorr;  if abs(invcorr)<u then invcorr=.;  else invcorr1=.;


  data outma; set outma;
  u95 = 1.96*stderr; l95=-1*u95;
  u=1/sqrt(300); l=-1*u;
  corr1=corr;  if abs(corr)<u95 then corr=.;  else corr1=.;
  pcorr1=partcorr;  if abs(partcorr)<u then partcorr=.;  else pcorr1=.;
  invcorr1=invcorr;  if abs(invcorr)<u then invcorr=.;  else invcorr1=.;
  data outarma; set outarma;
  u95 = 1.96*stderr; l95=-1*u95;
  u=1/sqrt(300); l=-1*u;
   corr1=corr;  if abs(corr)<u95 then corr=.;  else corr1=.;
  pcorr1=partcorr;  if abs(partcorr)<u then partcorr=.;  else pcorr1=.;
  invcorr1=invcorr;  if abs(invcorr)<u then invcorr=.;  else invcorr1=.;

proc gplot data=outar;
  title " ";
  label partcorr="PACF"; label corr="ACF"; label invcorr="IACF";
  plot (corr corr1 l95 u95)*lag/overlay hminor=0 vminor=0;
  symbol1 v=dot i=needle c=black w=5;
  symbol2 v=dot i=needle c=cyan w=5;
  symbol3 v=none i=join c=black w=5 ;
  symbol4 v=none i=join c=black w=5 ;
  plot (partcorr pcorr1 l u)*lag/overlay;
  plot (invcorr invcorr1 l u)*lag/overlay; run;

proc gplot data=outma;
  label partcorr="PACF"; label corr="ACF"; label invcorr="IACF";
  plot (corr corr1 l95 u95)*lag/overlay hminor=0 vminor=0;
  symbol1 v=dot i=needle c=red w=5;
  symbol2 v=dot i=needle c=cyan w=5;
  symbol3 v=none i=join c=black w=5 ;
  symbol4 v=none i=join c=black w=5 ;
  plot (partcorr pcorr1 l u)*lag/overlay;
  plot (invcorr invcorr1 l u)*lag/overlay; run;

proc gplot data=outarma;
  label partcorr="PACF"; label corr="ACF"; label invcorr="IACF";
  plot (corr corr1 l95 u95)*lag/overlay hminor=0 vminor=0;
  symbol1 v=dot i=needle c=green w=5;
  symbol2 v=dot i=needle c=cyan w=5;
  symbol3 v=none i=join c=black w=5 ;
  symbol4 v=none i=join c=black w=5 ;
  plot (partcorr pcorr1 l u)*lag/overlay;
  plot (invcorr invcorr1 l u)*lag/overlay; run;

  proc greplay tc=tempcat nofs igout=work.gseg;
  tdef ten des='Ten panels'

  1/ llx =  5   lly = 60
     ulx =  5   uly = 98
     urx = 95   ury = 98
     lrx = 95   lry = 60

   2/llx = 5   lly = 40
     ulx = 5   uly = 60
     urx =34   ury = 60
     lrx =34   lry = 40

   3/llx =36   lly = 40
     ulx =36   uly = 60
     urx =64   ury = 60
     lrx =64   lry = 40

   4/llx =66   lly = 40
     ulx =66   uly = 60
     urx =95   ury = 60
     lrx =95   lry = 40


   5/llx = 5   lly = 20
     ulx = 5   uly = 40
     urx =34   ury = 40
     lrx =34   lry = 20

   6/llx =36   lly = 20
     ulx =36   uly = 40
     urx =64   ury = 40
     lrx =64   lry = 20

   7/llx =66   lly = 20
     ulx =66   uly = 40
     urx =95   ury = 40
     lrx =95   lry = 20

   8/llx = 5   lly = 0
     ulx = 5   uly = 20
     urx =34   ury = 20
     lrx =34   lry = 0

   9/llx =36   lly = 0
     ulx =36   uly = 20
     urx =64   ury = 20
     lrx =64   lry = 0

   10/llx =66   lly = 0
      ulx =66   uly = 20
     urx =95   ury = 20
     lrx =95   lry = 0


;

   template = ten;

  treplay 1:gplot  2:gplot1 3:gplot2 4:gplot3 5:gplot4 6:gplot5
7:gplot6 8:gplot7 9:gplot8 10:gplot9; run;
 * replay template;

run ;
options ls=74;
proc arima data=a;
  i var=arma11
    scan p=(0:5) q=(0:5)
    minic p=(0:5) q=(0:5)
    esacf p=(0:5) q=(0:5)
    stationarity = (adf=(2,3,4));
run;